---
schema_version: "1"
id: 0fb7f3a90316200a30b30d42dbda3d703e7122348ebc0b5e952829abd957dceb
title: nodeExists
collection: mulesoft
version: current
locale: ja-jp
portal_url: https://docs.salesforce.com/mulesoft/current/ja-jp/dataweave/2.8/dw-tree-functions-nodeexists.md
canonical_url: https://docs.mulesoft.com/jp/dataweave/2.8/dw-tree-functions-nodeexists
source_site: docs.mulesoft.com
content_type: documentation
content_hash: ece1545f21ab8a46d57f29e29c29bbe939abcd3cd12a13d7d1bfc57e5aa33286
description: MuleSoft Documentation Site
release: "2.8"
latest: false
---
# nodeExists

## [](#nodeexists1)nodeExists(value: Any, callback: (value: Any, path: Path) -> Boolean): Boolean

特定のツリー内のいずれかのノードが、指定された条件に対して検証された場合、​`true`​ を返します。

_DataWeave バージョン 2.2.2 で導入されました。_

### [](#パラメーター)パラメーター

<table class="tableblock frame-all grid-all stretch">
<colgroup>
<col style="width: 25%;">
<col style="width: 75%;">
</colgroup>
<thead>
<tr>
<th class="tableblock halign-left valign-top">名前</th>
<th class="tableblock halign-left valign-top">説明</th>
</tr>
</thead>
<tbody>
<tr>
<td class="tableblock halign-left valign-top"><p class="tableblock"><code>value</code></p></td>
<td class="tableblock halign-left valign-top"><p class="tableblock">検索する値。</p></td>
</tr>
<tr>
<td class="tableblock halign-left valign-top"><p class="tableblock"><code>callback</code></p></td>
<td class="tableblock halign-left valign-top"><p class="tableblock">入力 ​<code>value</code>​ に適用する条件。</p></td>
</tr>
</tbody>
</table>

### [](#例)例

次の例では、名前と姓で各ユーザーをチェックします。​`value`​ を ​`$`​ で、​`path`​ を ​`$$`​ で参照することもできます。

#### [](#ソース)ソース

```DataWeave
%dw 2.0
import * from dw::util::Tree
var myObject =  {
     user: [{
         name: "mariano",
         lastName: "achaval",
         friends: [
             {
                 name: "julian"
             },
             {
                 name: "tom"
             }
         ]
     },
     {
         name: "leandro",
         lastName: "shokida",
         friends: [
             {
                 name: "peter"
             },
             {
                 name: "robert"
             }
         ]

     }
     ]
 }
output application/json
---
{
    mariano : myObject nodeExists ((value, path) -> path[-1].selector == "name" and value == "mariano"),
    julian : myObject nodeExists ((value, path) -> path[-1].selector == "name" and value == "julian"),
    tom : myObject nodeExists ($$[-1].selector == "name" and $ == "tom"),
    leandro : myObject nodeExists ($$[-1].selector == "name" and $ ==  "leandro"),
    peter : myObject nodeExists ($$[-1].selector == "name" and $ == "peter"),
    wrongField: myObject nodeExists ($$[-1].selector == "wrongField"),
    teo: myObject nodeExists ($$[-1].selector == "name" and $ == "teo")
}
```

#### [](#出力)出力

```Json
{
  "mariano": true,
  "julian": true,
  "tom": true,
  "leandro": true,
  "peter": true,
  "wrongField": false,
  "teo": false
}
```