Salesforce Docs Portal

--

--<S>(source: Array<S>, toRemove: Array<Any>): Array<S>

指定された値を入力値から削除します。

このバージョンの ​--​ は、指定された項目のすべてのインスタンスを配列から削除します。その他のバージョンは、DataWeave でサポートされるオブジェクト、文字列、およびさまざまな日付と時刻の形式で動作します。

名前 説明

ソース

削除する項目を含む配列。

toRemove

取得元配列から削除する項目。

例

次の例では、指定された項目を配列から削除します。具体的には、​--​ の右側の配列に含まれる項目のすべてのインスタンスをこの関数の左側の配列から削除します。結果として ​[0]​ が残ります。

ソース

%dw 2.0
output application/json
---
{ "a" : [0, 1, 1, 2] -- [1,2] }

出力

{ "a": [0] }

--<K, V>(source: { (K)?: V }, toRemove: Object): { (K)?: V }

オブジェクトから指定されたキー-値ペアを削除します。

パラメーター

名前 説明

source

取得元オブジェクト (​Object​ (オブジェクト) 型)。

toRemove

取得元オブジェクトから削除するキー-値ペアを含むオブジェクト。

例

次の例では、取得元オブジェクトからキー-値ペアを削除します。

ソース

%dw 2.0
output application/json
---
{ "hello" : "world", "name" : "DW" } -- { "hello" : "world"}

出力

{ "name": "DW" }

--(source: Object, keys: Array<String>)

指定された検索キーに一致する取得元オブジェクトからすべてのキー-値ペアを削除します。

パラメーター

名前 説明

source

取得元オブジェクト (​Object​ (オブジェクト) 型)。

toRemove

取得元オブジェクトから削除するキー-値ペアを指定するキーの配列。

例

次の例では、取得元オブジェクトから 2 つのキー-値ペアを削除します。

ソース

%dw 2.0
output application/json
---
{ "yes" : "no", "good" : "bad", "old" : "new" } -- ["yes", "old"]

出力

{ "good": "bad" }

--(source: Object, keys: Array<Key>)

オブジェクトから指定されたキー-値ペアを削除します。

パラメーター

名前 説明

source

取得元オブジェクト (​Object​ (オブジェクト) 型)。

keys

取得元オブジェクトから削除するキー-値ペアのキー。

例

次の例では、取得元オブジェクトから削除するキー-値ペアを指定します。

ソース

%dw 2.0
output application/json
---
{ "hello" : "world", "name" : "DW" } -- ["hello" as Key]

出力

{ "name": "DW" }

--(source: Null, keys: Any)

--​ を ​null​ 値に使用できるようにするヘルパー関数。

DataWeave バージョン 2.4.0 で導入されました。