---
schema_version: "1"
id: dbc13600ece8df84d7de6017fadac1d8ddc1d2be002b2388060fa16e44f32e16
title: XML タグへの属性の挿入
collection: mulesoft
version: current
locale: ja-jp
portal_url: https://docs.salesforce.com/mulesoft/current/ja-jp/dataweave/2.7/dataweave-cookbook-insert-attribute.md
canonical_url: https://docs.mulesoft.com/jp/dataweave/2.7/dataweave-cookbook-insert-attribute
source_site: docs.mulesoft.com
content_type: documentation
content_hash: e2ef46f5f2e11dccc0d70028335d335109a918b84dc31c32f91d2bd1122ea10a
description: MuleSoft Documentation Site
release: "2.7"
latest: false
---
# XML タグへの属性の挿入

この DataWeave の例では、​`@(key:value)`​ 構文 (​`@(loc: "US")`​ など) を使用して、属性を XML タグに挿入します。この例では、​`title`​ 要素に 2 つの属性を入力し、各 ​`author`​ 要素に 1 つの属性を入力します。 開始する前に、Mule 4 アプリケーションでは DataWeave のバージョン 2.x が使用されることに注意してください。Mule 3 アプリケーションでの DataWeave については、​[DataWeave バージョン 1.2 の例](#1.2@dataweave::dataweave-examples.adoc)​を参照してください。 他の DataWeave バージョンの場合は、DataWeave の目次のバージョンセレクターを使用できます。

次の関数を使用します。

- `mapObject`​: 変数 ​`myInput`​ で定義された入力 XML 内の各本を反復処理します。
- `map`​: 各本の ​`author`​ 要素を反復処理します。

DataWeave スクリプト:

```dataweave
%dw 2.0
var myInput = read('<bookstore>
  <book>
    <title>Everyday Italian</title>
    <year>2005</year>
    <price>30</price>
    <author>Giada De Laurentiis</author>
  </book>
  <book>
    <title>Harry Potter</title>
    <year>2005</year>
    <price>29.99</price>
    <author>J K. Rowling</author>
  </book>
  <book>
    <title>XQuery Kick Start</title>
    <year>2003</year>
    <price>49.99</price>
    <author>James McGovern</author>
    <author>Per Bothner</author>
    <author>Kurt Cagle</author>
    <author>James Linn</author>
    <author>Vaidyanathan Nagarajan</author>
  </book>
  <book>
    <title>Learning XML</title>
    <year>2003</year>
    <price>39.95</price>
    <author>Erik T. Ray</author>
  </book>
</bookstore>', 'application/xml')
output application/xml
---
bookstore: myInput.bookstore mapObject (book) -> {
      book : {
      title @(lang: "en", year: book.year): book.title,
      price: book.price,
      (book.*author map
      author @(loc: "US"): $)
    }
}
```

出力 XML:

```xml
<?xml version='1.0' encoding='UTF-8'?>
<bookstore>
  <book>
    <title lang="en" year="2005">Everyday Italian</title>
    <price>30</price>
    <author loc="US">Giada De Laurentiis</author>
  </book>
  <book>
    <title lang="en" year="2005">Harry Potter</title>
    <price>29.99</price>
    <author loc="US">J K. Rowling</author>
  </book>
  <book>
    <title lang="en" year="2003">XQuery Kick Start</title>
    <price>49.99</price>
    <author loc="US">James McGovern</author>
    <author loc="US">Per Bothner</author>
    <author loc="US">Kurt Cagle</author>
    <author loc="US">James Linn</author>
    <author loc="US">Vaidyanathan Nagarajan</author>
  </book>
  <book>
    <title lang="en" year="2003">Learning XML</title>
    <price>39.95</price>
    <author loc="US">Erik T. Ray</author>
  </book>
</bookstore>
```

## [](#関連する例)関連する例

- [自己終了 XML タグの出力](https://docs.mulesoft.com/jp/dataweave/2.7/dataweave-cookbook-output-self-closing-xml-tags)
- [指定した XML 属性の削除](https://docs.mulesoft.com/jp/dataweave/2.7/dataweave-cookbook-remove-certain-xml-attributes)
- [XML 名前空間を含める](https://docs.mulesoft.com/jp/dataweave/2.7/dataweave-cookbook-include-xml-namespaces)

## [](#関連情報)関連情報

- [DataWeave セレクター](https://docs.mulesoft.com/jp/dataweave/2.7/dataweave-selectors)
- [DataWeave の解説書](https://docs.mulesoft.com/jp/dataweave/2.7/dataweave-cookbook)