---
schema_version: "1"
id: b02cedc783c82d5b92b2089e6532cc2f69ebed31a677c088851dfe258f41863e
title: DataWeave でのデフォルト値の設定
collection: mulesoft
version: current
locale: ja-jp
portal_url: https://docs.salesforce.com/mulesoft/current/ja-jp/dataweave/2.6/dataweave-cookbook-defaults.md
canonical_url: https://docs.mulesoft.com/jp/dataweave/2.6/dataweave-cookbook-defaults
source_site: docs.mulesoft.com
content_type: documentation
content_hash: b2ca7dfa0d4d5671f86b45cc9bf1158934f0b519900f107d6044efd6ec742f11
description: MuleSoft Documentation Site
release: "2.6"
latest: false
---
# DataWeave でのデフォルト値の設定

ペイロード値がない場合やその値が ​`null`​ である場合にデフォルト値を設定するには次のいずれかの方法を使用します。

- `default`​ キーワードを使用する。
- `if-else`​ または ​`else-if`​ ステートメントでデフォルトを設定する。
- パターンを照合するときに ​`else`​ を使用する。

開始する前に、Mule 4 アプリケーションでは DataWeave のバージョン 2.x が使用されることに注意してください。Mule 3 アプリケーションでの DataWeave については、​[DataWeave バージョン 1.2 の例](#1.2@dataweave::dataweave-examples.adoc)​を参照してください。 他の DataWeave バージョンの場合は、DataWeave の目次のバージョンセレクターを使用できます。

## [](#キーワード-default-を使用したデフォルト値設定の例)キーワード default を使用したデフォルト値設定の例

`id`​ 項目と ​`name`​ 項目を含む JSON 入力を想定し、変換を行うアプリケーションについて考えます。 これらの項目が存在しないか、値が ​`null`​ である場合のデフォルト値を設定できます。次に例を示します。

DataWeave スクリプト:

```dataweave
%dw 2.0
output application/json
---
{
  "userId": payload.id default "0000",
  "userName": payload.name default "Undefined"
}
```

このアプリケーションが ​`id`​ 項目と ​`name`​ 項目に値が設定された JSON メッセージを受信すると、DataWeave 変換によって ​`id`​ 項目が ​`userId`​ に照合され、​`name`​ 項目が ​`userName`​ に照合されます。

入力 JSON ペイロード:

```json
{
  "id": "123",
  "name": "Max the Mule"
}
```

出力 JSON:

```json
{
  "userId": "123",
  "userName": "Max the Mule"
}
```

ただし、アプリケーションが受信した JSON メッセージに想定される項目がない場合や項目の値が ​`null`​ である場合は、変換では ​`userId`​ 項目と ​`userName`​ 項目に設定されたデフォルト値が使用されます。

入力 JSON ペイロード:

```json
{
  "id": null
}
```

出力 JSON:

```json
{
  "userId": "0000",
  "userName": "Undefined"
}
```

## [](#ex03)if-else と else-if ステートメントを使用したデフォルト値設定の例

デフォルト値を設定する別の方法は、​[if-else](https://docs.mulesoft.com/jp/dataweave/2.6/dataweave-flow-control#control_flow_if_else)​ と ​[else-if](https://docs.mulesoft.com/jp/dataweave/2.6/dataweave-flow-control#control_flow_else_if)​ を使用するものです。

次の例では、JSON 入力メッセージの ​`userLocation`​ が存在しない場合やその値が ​`null`​ である場合にデフォルト値として ​`United States`​ を設定します。

DataWeave スクリプト:

```dataweave
%dw 2.0
output application/json
---
if (payload.location != null) {
	"userLocation" : payload.location
} else {
	"userLocation" : "United States"
}
```

このアプリケーションが ​`location`​ 項目に値が設定された JSON メッセージを受信すると、DataWeave 変換によって ​`location`​ 項目が ​`userLocation`​ に照合されます。

入力 JSON ペイロード:

```json
{
  "location": "Argentina"
}
```

出力 JSON:

```json
{
  "userLocation": "Argentina"
}
```

ただし、アプリケーションが受信した JSON メッセージに想定される項目がない場合や項目の値が ​`null`​ である場合は、変換では ​`userLocation`​ 項目に設定されたデフォルト値が使用されます。

入力 JSON ペイロード:

```json
{}
```

出力 JSON:

```json
{
  "userLocation": "United States"
}
```

## [](#ex05)照合パターンを使用したデフォルト値設定の例

[パターンを照合するスクリプト](https://docs.mulesoft.com/jp/dataweave/2.6/dataweave-pattern-matching)​の場合、DataWeave の ​`case`​ ステートメントは ​`else`​ 式で終了します。これは、先行するすべての ​`case`​ 式で ​`false`​ が返された場合に返されるデフォルトとして機能します。

DataWeave スクリプト:

```dataweave
%dw 2.0
var myVar = "someString"
output application/json
---
myVar match {
    case myVarOne if (myVar == "some") -> ("some" ++ "is myVar")
    case myVarOne if (myVar == "strings") -> ("strings" ++ "is myVar")
    else -> myVar ++ " is myVar"
}
```

出力 JSON:

```json
"someString is myVar"
```