---
schema_version: "1"
id: 73d72cd0c07d4f051200621e66aa55667d1e3f306d5ea3eaa870d370654fe0c8
title: everyEntry
collection: mulesoft
version: current
locale: en-us
portal_url: https://docs.salesforce.com/mulesoft/current/en-us/dataweave/2.4/dw-objects-functions-everyentry.md
canonical_url: https://docs.mulesoft.com/dataweave/2.4/dw-objects-functions-everyentry
source_site: docs.mulesoft.com
content_type: documentation
content_hash: 7d036e05f90c7e49d9d124fe9555a57147672daa30d81ae53813c1f7d2fb3ad1
description: MuleSoft Documentation Site
release: "2.4"
latest: false
---
---
product: DataWeave
version: 2.4
---

# everyEntry

> For the full documentation index, see: https://docs.mulesoft.com/llms.txt

## everyEntry(object: Object, condition: (value: Any, key: Key) -> Boolean): Boolean

Returns `true` if every entry in the object matches the condition.

The function stops iterating after the first negative evaluation of an element in the object.

_Introduced in DataWeave version 2.3.0._

### Parameters

<table><colgroup><col> <col></colgroup><thead><tr><th>Name</th><th>Description</th></tr></thead><tbody><tr><td><p><code>object</code></p></td><td><p>The object to evaluate.</p></td></tr><tr><td><p><code>condition</code></p></td><td><p>The condition to apply to each element.</p></td></tr></tbody></table>

### Example

This example shows how `everyEntry` behaves with different inputs.

#### Source

```DataWeave
%dw 2.0
import everyEntry from dw::core::Objects
output application/json
---
{
    a: {} everyEntry (value, key) -> value is String,
    b: {a: "", b: "123"} everyEntry (value, key) -> value is String,
    c: {a: "", b: 123} everyEntry (value, key) -> value is String,
    d: {a: "", b: 123} everyEntry (value, key) -> key as String == "a",
    e: {a: ""} everyEntry (value, key) -> key as String == "a",
    f: null everyEntry ((value, key) -> key as String == "a")
}
```

#### Output

```Json
{
  "a": true,
  "b": true,
  "c": false,
  "d": false,
  "e": true,
  "f": true
}
```

## everyEntry(list: Null, condition: (Nothing, Nothing) -> Boolean): Boolean

Helper function that enables `everyEntry` to work with a `null` value.

_Introduced in DataWeave version 2.3.0._