Salesforce Docs Portal

bulkIssueInsurancePolicy(insurancePolicyBulkInput)

Issue policies in bulk for the specified insurance policy IDs.

API Version

67.0

Requires Chatter

No

Signature

public static ConnectApi.InsurancePolicyBulkOutputRepresentation bulkIssueInsurancePolicy(ConnectApi.InsurancePolicyBulkInputRepresentation insurancePolicyBulkInput)

Parameters

insurancePolicyBulkInput

Return Value

Type: ConnectApi.InsurancePolicyBulkOutputRepresentation

Usage

Use this method to issue insurance policies in bulk. The JSON input includes a field value map of insurance policy fields and a list of insurance policy IDs. After the request is successfully sent to the message queue, policies are issued asynchronously, and you receive either a success or failure notification after the completion of the request.

Example

The Apex example shows how to use the ConnectApi.InsuranceBrokerageFamily.bulkIssueInsurancePolicy() method to issue multiple insurance policies in bulk.

Class Definition

This Apex example shows how to issue multiple policies in bulk.

global class BulkIssueConnectDriver {

    global static void callBulkIssueConnectAPI() {
        Map<String, Object> input = new Map<String, Object>();

        ConnectApi.InsurancePolicyBulkInputRepresentation bulkInput = new ConnectApi.InsurancePolicyBulkInputRepresentation();

        List<String> policyIds = new List<String>{
            '0YTxx000000001dGAA',
            '0YTxx000000002dGAA',
            '0YTxx000000003dGAA'
        };
        bulkInput.insurancePolicyIds = policyIds;

        input.put('bulkInput', bulkInput);

        Map<String, Object> output = new Map<String, Object>();
        Map<String, Object> args = new Map<String, Object>();
        args.put('input', input);
        args.put('output', output);

        BulkIssueTestConnectAPI callable = new BulkIssueTestConnectAPI();
        Object result = callable.call('bulkIssue', args);

        ConnectApi.InsurancePolicyBulkOutputRepresentation bulkData =
            (ConnectApi.InsurancePolicyBulkOutputRepresentation) result;
        System.debug('Bulk Issue Data: ' + JSON.serializePretty(bulkData));

        if (output.containsKey('error')) {
            System.debug('Error: ' + output.get('error'));
        }
    }
}

Usage Example

Use the BulkIssueTestConnectAPI class to execute the bulkIssue action and process the result.

public class BulkIssueTestConnectAPI implements System.Callable {

    public Object call(String action, Map<String, Object> args) {
        Map<String, Object> inputMap = (Map<String, Object>) args.get('input');
        Map<String, Object> outputMap = (Map<String, Object>) args.get('output');

        if (action == 'bulkIssue') {
            ConnectApi.InsurancePolicyBulkInputRepresentation bulkInput =
                (ConnectApi.InsurancePolicyBulkInputRepresentation) inputMap.get('bulkInput');
            System.debug('Start of Connect API call to bulk issue policies');

            ConnectApi.InsurancePolicyBulkOutputRepresentation bulkData;
            try {
                bulkData = ConnectApi.InsuranceBrokerageFamily.bulkIssueInsurancePolicy(bulkInput);
                System.debug('Policies bulk issued successfully: ' + bulkData);
                outputMap.put('bulkData', bulkData);
            } catch (Exception e) {
                System.debug('Error while bulk issuing policies: ' + e.getMessage());
                outputMap.put('error', e.getMessage());
            }
            return bulkData;
        }

        return null;
    }
}

// Execute
BulkIssueConnectDriver.callBulkIssueConnectAPI();