Salesforce Docs Portal

bulkCancelInsurancePolicy(insurancePolicyBulkInput)

Cancel policies in bulk for the specified Insurance Policy IDs.

API Version

64.0

Requires Chatter

No

Signature

public static ConnectApi.InsurancePolicyBulkOutputRepresentation bulkCancelInsurancePolicy(ConnectApi.InsurancePolicyBulkInputRepresentation insurancePolicyBulkInput)

Parameters

insurancePolicyBulkInput

Return Value

Type: ConnectApi.InsurancePolicyBulkOutputRepresentation

Usage

Use this method to cancel insurance policies in bulk. The JSON input includes a field value map of insurance policy fields, such as CancellationEffectiveDate, Status, and CancellationReason, and a list of insurance policy IDs. After the request is successfully sent to the message queue, policies are canceled asynchronously, and you receive either a success or failure notification after the completion of the request.

Example

The Apex example shows how to use the ConnectApi.InsuranceBrokerageFamily.bulkCancelInsurancePolicy() method to cancel multiple insurance policies in bulk.

Class Definition

This Apex example shows how to cancel multiple policies in bulk.

global class BulkCancelConnectDriver {

    global static void callBulkCancelConnectAPI() {
        Map<String, Object> input = new Map<String, Object>();

        ConnectApi.InsurancePolicyBulkInputRepresentation bulkInput = new ConnectApi.InsurancePolicyBulkInputRepresentation();

        List<String> policyIds = new List<String>{
            '0YTxx000000001dGAA',
            '0YTxx000000002dGAA',
            '0YTxx000000003dGAA'
        };
        bulkInput.insurancePolicyIds = policyIds;

        Map<String, Object> fields = new Map<String, Object>();
        fields.put('CancellationReason', 'Batch Cancellation');
        fields.put('CancellationEffectiveDate', '2026-07-01');
        bulkInput.fieldValueMap = fields;

        input.put('bulkInput', bulkInput);

        Map<String, Object> output = new Map<String, Object>();
        Map<String, Object> args = new Map<String, Object>();
        args.put('input', input);
        args.put('output', output);

        BulkCancelTestConnectAPI callable = new BulkCancelTestConnectAPI();
        Object result = callable.call('bulkCancel', args);

        ConnectApi.InsurancePolicyBulkOutputRepresentation bulkData =
            (ConnectApi.InsurancePolicyBulkOutputRepresentation) result;
        System.debug('Bulk Cancel Data: ' + JSON.serializePretty(bulkData));

        if (output.containsKey('error')) {
            System.debug('Error: ' + output.get('error'));
        }
    }
}

Usage Example

Use the BulkCancelTestConnectAPI class to execute the bulkCancel action and process the result.

public class BulkCancelTestConnectAPI implements System.Callable {

    public Object call(String action, Map<String, Object> args) {
        Map<String, Object> inputMap = (Map<String, Object>) args.get('input');
        Map<String, Object> outputMap = (Map<String, Object>) args.get('output');

        if (action == 'bulkCancel') {
            ConnectApi.InsurancePolicyBulkInputRepresentation bulkInput =
                (ConnectApi.InsurancePolicyBulkInputRepresentation) inputMap.get('bulkInput');
            System.debug('Start of Connect API call to bulk cancel policies');

            ConnectApi.InsurancePolicyBulkOutputRepresentation bulkData;
            try {
                bulkData = ConnectApi.InsuranceBrokerageFamily.bulkCancelInsurancePolicy(bulkInput);
                System.debug('Policies bulk cancelled successfully: ' + bulkData);
                outputMap.put('bulkData', bulkData);
            } catch (Exception e) {
                System.debug('Error while bulk cancelling policies: ' + e.getMessage());
                outputMap.put('error', e.getMessage());
            }
            return bulkData;
        }

        return null;
    }
}

// Execute

BulkCancelConnectDriver.callBulkCancelConnectAPI();