IIndividualPartyManagementPATCH Apex Interface

The IIndividualPartyManagementPATCH Apex interface provides extensibility for PATCH operations through Apex pre- and post-hooks and GraphQL query customization. Implementations can validate incoming requests, modify query structures, and refine the response to support business-specific retrieval rules while maintaining TMF-compliant behavior.

This interface supports the following hooks.

• transformRequest
• configureDefaultValidations
• applyCustomValidations
• customiseMutationPayload
• handlePostOperation

Update Operation Use Cases

transformRequest

This hook transforms the request context before processing any operation. It is invoked early in the request lifecycle, allowing implementers to adjust the context for subsequent extensibility hooks.

Hook Method

Map<String, Object> transformRequest(Map<String, Object> context)

Sample Apex Implementation

Prevent updates to familyName.

global class IndividualPatchTransformRequestExt implements comms_apex_ext.IIndividualPartyManagementPATCH {


    global static Map<String, Object> transformRequest(Map<String, Object> context) {
        if (context != null && context.get('requestBody') instanceof Map<String, Object>) {
            Map<String, Object> body = (Map<String, Object>) context.get('requestBody');
            // Business rule: last name changes must go through a separate governance flow.
            body.remove('familyName');
        }
        return context;
    }


    // ... other hooks return null / empty map ...
}

configureDefaultValidations

This hook enables, disables, or modifies the built-in validation rules before they execute.

Hook Method

Map<String, Boolean> configureDefaultValidations(Map<String, Boolean> defaultValidationConfiguration, Map<String, Object> context)

Sample Apex Implementation

Add a custom flag consumed by applyCustomValidations.

global class IndividualPatchConfigValidationsExt implements comms_apex_ext.IIndividualPartyManagementPATCH {


    global static Map<String, Boolean> configureDefaultValidations(
        Map<String, Boolean> defaultValidationConfiguration,
        Map<String, Object> context
    ) {
        Map<String, Boolean> overrides = defaultValidationConfiguration != null
            ? defaultValidationConfiguration.clone()
            : new Map<String, Boolean>();
        overrides.put('emailDomainCheck', true);   // your own flag, read in applyCustomValidations
        return overrides;
    }


    // ... other hooks return null / empty map ...
}

applyCustomValidations

This hook validates custom business logic before retrieving customer record. If validation fails, it rejects the request and returns an error response.

The handler processes return values as follows.

Success:

• Return a map with validationStatus set to "pass" (case-insensitive).
• The API request continues normally.
• Other fields in the map are logged but not used.

Failure:

• Return a map with validationStatus set to "fail" (case-insensitive).
• The API request is terminated immediately.
• Raise a ValidationException containing
  • message: value from validationMessage key (or "Validation failed" by default)
  • details: value from validationDetails key (optional)
• The client receives an HTTP 400 error response.

Hook Method

Map<String, Object> applyCustomValidations(Map<String, Object> context)

Sample Apex Implementation

Validate the updated email domain.

global class IndividualPatchValidationExt implements comms_apex_ext.IIndividualPartyManagementPATCH {


    global static Map<String, Object> applyCustomValidations(Map<String, Object> context) {
        Map<String, Object> result = new Map<String, Object>();
        if (!(context.get('requestBody') instanceof Map<String, Object>)) {
            return result;
        }
        Map<String, Object> body = (Map<String, Object>) context.get('requestBody');


        if (body.get('contactMedium') instanceof List<Object>) {
            for (Object cmObj : (List<Object>) body.get('contactMedium')) {
                Map<String, Object> cm = (Map<String, Object>) cmObj;
                if ('EmailContactMedium'.equals(cm.get('@type'))) {
                    String email = (String) cm.get('emailAddress');
                    if (email != null && !email.endsWithIgnoreCase('@acme.com')) {
                        result.put('validationStatus', 'fail');
                        result.put('validationMessage',
                            'Email domain not allowed. Individuals must use an @acme.com address.');
                    }
                }
            }
        }
        return result;   // empty => proceed; validationStatus="fail" => HTTP 400
    }


    // ... other hooks return null / empty map ...
}

customiseMutationPayload

This hook modifies the GraphQL query before execution to add fields, filters, or transformations.

Hook Method

Map<String, Object> customiseMutationPayload(Map<String, Object> graphQLAsMap,Map<String, Object> context)

Sample Apex Implementation

Stamp an audit field on update.

global class IndividualPatchCustomMutationExt implements comms_apex_ext.IIndividualPartyManagementPATCH {
    global static Map<String, Object> customiseMutationPayload(
        Map<String, Object> graphQLAsMap,
        Map<String, Object> context
    ) {
        Map<String, Object> node = new Map<String, Object>{
            'path' => 'individualData',
            'addFields' => new Map<String, Object>{
                'Last_API_Update__c' => 'TMF632-PATCH'
            }
        };
        return new Map<String, Object>{
            'nodes' => new List<Object>{ node }
        };
    }
    // ... other hooks return null / empty map ...
}

handlePostOperation

This hook post-processes and transforms the API response after data retrieval.

Hook Method

Map<String, Object> handlePostOperation(Map<String, Object> graphQLQueryResultAsMap, Map<String, Object> constructedTMFResponse, Map<String, Object> context)

Sample Apex Implementation

Enrich the response in place.

global class IndividualPatchEnrichExt implements comms_apex_ext.IIndividualPartyManagementPATCH {


    global static Map<String, Object> handlePostOperation(
        Map<String, Object> graphQLQueryResultAsMap,
        Map<String, Object> constructedTMFResponse,
        Map<String, Object> context
    ) {
        if (constructedTMFResponse != null) {
            constructedTMFResponse.put('updatedBy', UserInfo.getName());
            constructedTMFResponse.put('lastUpdatedAt',
                DateTime.now().format('yyyy-MM-dd\'T\'HH:mm:ss\'Z\''));
        }
        return null;   // keeps the mutated response as the final payload
    }


    // ... other hooks return null / empty map ...
}

Full Implementation Example

Here's a complete sample Apex implementation using all supported hooks.

/**
 * Complete TMF632 Individual (Party Management) PATCH API extension,
 * demonstrating all hooks with business logic.
 */
global class IndividualPartyManagementPATCHExtension implements comms_apex_ext.IIndividualPartyManagementPATCH {


    // Hook 1: prevent familyName updates via the API.
    global static Map<String, Object> transformRequest(Map<String, Object> context) {
        if (context != null && context.get('requestBody') instanceof Map<String, Object>) {
            ((Map<String, Object>) context.get('requestBody')).remove('familyName');
        }
        return context;
    }


    // Hook 2: PATCH has no default validators; keep it that way.
    global static Map<String, Boolean> configureDefaultValidations(
        Map<String, Boolean> defaultValidationConfiguration,
        Map<String, Object> context
    ) {
        return new Map<String, Boolean>();
    }


    // Hook 3: enforce the corporate email domain on update.
    global static Map<String, Object> applyCustomValidations(Map<String, Object> context) {
        Map<String, Object> result = new Map<String, Object>();
        if (context.get('requestBody') instanceof Map<String, Object>) {
            Map<String, Object> body = (Map<String, Object>) context.get('requestBody');
            if (body.get('contactMedium') instanceof List<Object>) {
                for (Object cmObj : (List<Object>) body.get('contactMedium')) {
                    Map<String, Object> cm = (Map<String, Object>) cmObj;
                    if ('EmailContactMedium'.equals(cm.get('@type'))) {
                        String email = (String) cm.get('emailAddress');
                        if (email != null && !email.endsWithIgnoreCase('@acme.com')) {
                            result.put('validationStatus', 'fail');
                            result.put('validationMessage',
                                'Email domain not allowed. Individuals must use an @acme.com address.');
                        }
                    }
                }
            }
        }
        return result;
    }


    // Hook 4: stamp an audit field on update.
    global static Map<String, Object> customiseMutationPayload(
        Map<String, Object> graphQLAsMap,
        Map<String, Object> context
    ) {
        Map<String, Object> node = new Map<String, Object>{
            'path' => 'individualData',
            'addFields' => new Map<String, Object>{ 'Last_API_Update__c' => 'TMF632-PATCH' }
        };
        return new Map<String, Object>{ 'nodes' => new List<Object>{ node } };
    }


    // Hook 5: enrich the response in place.
    global static Map<String, Object> handlePostOperation(
        Map<String, Object> graphQLQueryResultAsMap,
        Map<String, Object> constructedTMFResponse,
        Map<String, Object> context
    ) {
        if (constructedTMFResponse != null) {
            constructedTMFResponse.put('updatedBy', UserInfo.getName());
        }
        return null;
    }
}