IIndividualPartyManagementDELETE Apex Interface

The IIndividualPartyManagementDELETE interface provides extensibility for DELETE operations through Apex-based validations, mutation-payload adjustments, and post-operation processing. Users can enforce deletion policies, apply soft-delete or metadata logic, and customize final responses without impacting TMF-compliant delete behavior.

This interface supports the following hooks.

• transformRequest
• configureDefaultValidations
• applyCustomValidations
• customiseMutationPayload
• handlePostOperation

note: The customiseGraphQLQuery is not applicable to DELETE, which is a write operation, so there is no read query to customize. This hook is declared on the read interface (ICommsGET), not on ICommsDELETE. To customize the soft-delete mutation payload, use customiseMutationPayload.

Deletion Lifecycle Use Cases and Hook Mapping

This table lists common use cases and the hooks required for the DELETE operation.

transformRequest

This hook transforms the request context before processing any operation. It is invoked early in the request lifecycle, allowing implementers to adjust the context for subsequent extensibility hooks.

Hook Method

Map<String, Object> transformRequest(Map<String, Object> context)

Sample Apex Implementation

Resolve an external ID to a Salesforce Contact ID.

global class IndividualDeleteTransformRequestExt implements comms_apex_ext.IIndividualPartyManagementDELETE {


    global static Map<String, Object> transformRequest(Map<String, Object> context) {
        if (context == null || !(context.get('id') instanceof String)) {
            return context;
        }
        String idValue = (String) context.get('id');
        if (idValue.length() != 15 && idValue.length() != 18) {
            List<Contact> matches = [
                SELECT Id FROM Contact WHERE External_Id__c = :idValue LIMIT 1
            ];
            if (!matches.isEmpty()) {
                context.put('id', matches[0].Id);
            }
        }
        return context;
    }


    // customiseMutationPayload still REQUIRED — see HOOK 4 ...
}

configureDefaultValidations

This hook enables, disables, or modifies the built-in validation rules before they execute.

Hook Method

Map<String, Boolean> configureDefaultValidations(Map<String, Boolean> defaultValidationConfiguration, Map<String, Object> context)

Sample Apex Implementation

Add a custom flag consumed by applyCustomValidations.

global class IndividualDeleteConfigValidationsExt implements comms_apex_ext.IIndividualPartyManagementDELETE {


    global static Map<String, Boolean> configureDefaultValidations(
        Map<String, Boolean> defaultValidationConfiguration,
        Map<String, Object> context
    ) {
        Map<String, Boolean> overrides = defaultValidationConfiguration != null
            ? defaultValidationConfiguration.clone()
            : new Map<String, Boolean>();
        overrides.put('checkOpenOrders', true);   // your own flag, read in applyCustomValidations
        return overrides;
    }


    // customiseMutationPayload still REQUIRED — see HOOK 4 ...
}

applyCustomValidations

This hook validates custom business logic before retrieving customer record. If validation fails, it rejects the request and returns an error response.

The handler processes return values as follows.

Success:

• Return a map with validationStatus set to "pass" (case-insensitive).
• The API request continues normally.
• Other fields in the map are logged but not used.

Failure:

• Return a map with validationStatus set to "fail" (case-insensitive).
• The API request is terminated immediately.
• Raise a ValidationException containing
  • message: value from validationMessage key (or "Validation failed" by default)
  • details: value from validationDetails key (optional)
• The client receives an HTTP 400 error response.

Hook Method

Map<String, Object> applyCustomValidations(Map<String, Object> context)

Sample Apex Implementation

Prevent deletion when the Individual party has open order.

global class IndividualDeletePreventExt implements comms_apex_ext.IIndividualPartyManagementDELETE {


    global static Map<String, Object> applyCustomValidations(Map<String, Object> context) {
        Map<String, Object> result = new Map<String, Object>();
        String individualId = (String) context.get('id');
        if (individualId != null) {
            Integer openOrders = [
                SELECT COUNT() FROM Order
                WHERE (BillToContactId = :individualId OR ShipToContactId = :individualId)
                  AND Status = 'Activated'
            ];
            if (openOrders > 0) {
                result.put('validationStatus', 'fail');
                result.put('validationMessage',
                    'Cannot delete this Individual - deletion prevented by custom validation');
            }
        }
        return result;   // empty => proceed; validationStatus="fail" => HTTP 422
    }


    // customiseMutationPayload still REQUIRED — see HOOK 4 ...
}

customiseMutationPayload

This hook modifies the mutation payload before deleting a customer record. Use this to add deletion metadata, set soft-delete flags, or apply business logic transformations.

Hook Method

Map<String, Object> customiseMutationPayload(Map<String, Object> request, Map<String, Object> context)

Sample Apex Implementation

Supply the soft-delete status field.

global class IndividualDeleteCustomMutationExt implements comms_apex_ext.IIndividualPartyManagementDELETE {


    global static Map<String, Object> customiseMutationPayload(
        Map<String, Object> graphQLAsMap,
        Map<String, Object> context
    ) {
        Map<String, Object> node = new Map<String, Object>{
            'path'      => 'softDeleteIndividual',
            'addFields' => new Map<String, Object>{
                'Status__c'          => 'Inactive',
                'Deletion_Reason__c' => 'Deleted via TMF632 Individual API'
            }
        };
        return new Map<String, Object>{
            'nodes' => new List<Object>{ node }
        };
    }
    // ... other hooks return null / empty map ...
}

handlePostOperation

This hook post-processes and transforms the API response after data retrieval.

Hook Method

Map<String, Object> handlePostOperation(Map<String, Object> graphQLQueryResultAsMap, Map<String, Object> constructedTMFResponse, Map<String, Object> context)

Sample Apex Implementation

Audit the deletion.

global class IndividualDeleteHandlePostOpExt implements comms_apex_ext.IIndividualPartyManagementDELETE {


    global static Map<String, Object> handlePostOperation(
        Map<String, Object> graphQLQueryResultAsMap,
        Map<String, Object> constructedTMFResponse,
        Map<String, Object> context
    ) {
        Object dr = context != null ? context.get('deleteResult') : null;
        if (dr instanceof Map<String, Object>) {
            Map<String, Object> deleteResult = (Map<String, Object>) dr;
            if (Boolean.TRUE.equals(deleteResult.get('success'))) {
                insert new Individual_Deletion_Log__c(
                    Individual_Id__c = (String) deleteResult.get('deletedId'),
                    Deleted_By__c    = UserInfo.getUserId()
                );
            }
        }
        return null;   // no body for HTTP 204
    }


    // customiseMutationPayload still REQUIRED — see HOOK 4 ...
}

Full Implementation Example

Here's a complete sample Apex implementation using all supported hooks.

/**
 * Complete TMF632 Individual (Party Management) DELETE API extension,
 * demonstrating all hooks. customiseMutationPayload supplies the required soft-delete field.
 */
global class IndividualPartyManagementDELETEExtension implements comms_apex_ext.IIndividualPartyManagementDELETE {


    // Hook 1: normalize / resolve the id.
    global static Map<String, Object> transformRequest(Map<String, Object> context) {
        return context;
    }


    // Hook 2: DELETE has no default validators; keep it that way.
    global static Map<String, Boolean> configureDefaultValidations(
        Map<String, Boolean> defaultValidationConfiguration,
        Map<String, Object> context
    ) {
        return new Map<String, Boolean>();
    }


    // Hook 3: block deletion when there are active orders.
    global static Map<String, Object> applyCustomValidations(Map<String, Object> context) {
        Map<String, Object> result = new Map<String, Object>();
        String individualId = (String) context.get('id');
        if (individualId != null) {
            Integer openOrders = [
                SELECT COUNT() FROM Order
                WHERE (BillToContactId = :individualId OR ShipToContactId = :individualId)
                  AND Status = 'Activated'
            ];
            if (openOrders > 0) {
                result.put('validationStatus', 'fail');
                result.put('validationMessage',
                    'Cannot delete this Individual - deletion prevented by custom validation');
            }
        }
        return result;
    }


    // Hook 4 (REQUIRED): supply the soft-delete status field on the softDeleteIndividual node.
    global static Map<String, Object> customiseMutationPayload(
        Map<String, Object> graphQLAsMap,
        Map<String, Object> context
    ) {
        Map<String, Object> node = new Map<String, Object>{
            'path'      => 'softDeleteIndividual',
            'addFields' => new Map<String, Object>{ 'Status__c' => 'Inactive' }
        };
        return new Map<String, Object>{ 'nodes' => new List<Object>{ node } };
    }


    // Hook 5: audit the deletion (no response body).
    global static Map<String, Object> handlePostOperation(
        Map<String, Object> graphQLQueryResultAsMap,
        Map<String, Object> constructedTMFResponse,
        Map<String, Object> context
    ) {
        Object dr = context != null ? context.get('deleteResult') : null;
        if (dr instanceof Map<String, Object>
            && Boolean.TRUE.equals(((Map<String, Object>) dr).get('success'))) {
            // audit / downstream cleanup
        }
        return null;
    }
}